% V20210224 - 10.6 GW_FOCUS

ARRAY.LOAD buzz[], 1, 100

% Load the GW library
INCLUDE "GW.bas"

% Create a new page
p = GW_NEW_PAGE()

% Add the needed input controls

GW_ADD_TITLE(p, "Personal Information")
firstname = GW_ADD_INPUTLINE(p, "First Name:", "")
lastname = GW_ADD_INPUTLINE(p, "Last Name:", "")
dateofbirth = GW_ADD_INPUTDATE(p, "Date of Birth:", "")
address = GW_ADD_INPUTLINE(p, "Ship To:", "")
phone = GW_ADD_INPUTTEL(p, "Phone number:", "")
GW_ADD_TITLE(p, "Web Account")
email = GW_ADD_INPUTEMAIL(p, "Email address:", "")
password1 = GW_ADD_INPUTPASSWORD(p, "Type your password", "")
password2 = GW_ADD_INPUTPASSWORD(p, "Confirm your password", "")

% Add the validation button
GW_ADD_BUTTON(p, "Register Form", "REG")

% Show the page
GW_RENDER(p)

% Get user actions
DO
  r$ = GW_WAIT_ACTION$()
  IF r$="REG"
    err = 0
    ctl = firstname   : GOSUB CheckControl
    ctl = lastname    : GOSUB CheckControl
    ctl = dateofbirth : GOSUB CheckControl
    ctl = address     : GOSUB CheckControl
    ctl = phone       : GOSUB CheckControl
    ctl = email       : GOSUB CheckControl
    ctl = password1   : GOSUB CheckControl
    ctl = password2   : GOSUB CheckControl
    IF GW_GET_VALUE$(password1) <> GW_GET_VALUE$(password2)
      POPUP "Passwords don't match!"
      ctl = password2
      GOSUB ShowWarning
    ENDIF
    IF err = 0 THEN END "Registration Ok!"
  ENDIF
UNTIL r$= "BACK"

END "Registration Canceled :("

CheckControl:
v$ = GW_GET_VALUE$(ctl)
IF v$ = "" | v$ = "<empty>"
  err = err+1
  GOSUB ShowWarning
ELSE
  GW_MODIFY(ctl, "style:color", "green")
ENDIF
RETURN

ShowWarning:
GW_MODIFY(ctl, "input", "<empty>")
IF ctl < password1 THEN GW_MODIFY(ctl, "style:color", "red")
IF err = 1
  GW_FOCUS(ctl)
  VIBRATE buzz[], -1
  POPUP "Error - Please correct"
ENDIF
RETURN